Defining last nine rows of data as range to copy values and transpose paste into another worksheet

Question

What VBA code should be used to provide a range that always includes the latest nine rows of data?

I have a data table with 9 subjects that is manually updated each month. I want to duplicate some cell values from the most recent entries and use them to fill out a scorecard on another worksheet.

Determining a dynamic range from the ninth row up is something I can't seem to figure out how to do.

I can define the last row using

Last = Cells(Rows.Count, “B”).End(xlUp).Row

But how do I define the last 9 rows?

Last = Cells(Rows.Count, “B”).End(xlUp).Row

‘First???

For i=Last To ‘first Step -1

‘If “name” then copy cell values to the defined cell in the scorecard

Answer 1

Transpose Last Rows

Sub PrintLastRowsAddress()

    Const LAST_ROWS_COUNT As Long = 9
 
    Dim ws As Worksheet: Set ws = ActiveSheet ' improve!
    
    Dim lrg As Range

    With ws.UsedRange
        Set lrg = .Resize(LAST_ROWS_COUNT).Offset(.Rows.Count - LAST_ROWS_COUNT)
    End With
    
    Debug.Print lrg.Address(0, 0)
    
End Sub

Sub TransposeLastRows()

    Const SRC_NAME As String = "Sheet1"
    Const SRC_LAST_ROWS As Long = 9
    Const DST_NAME As String = "Sheet2"
    Const DST_FIRST_CELL As String = "A1"
 
    Dim wb As Workbook: Set wb = ThisWorkbook ' workbook containing this code
    
    Dim sws As Worksheet: Set sws = wb.Sheets(SRC_NAME)
    Dim srg As Range
    With sws.UsedRange
        Set srg = .Resize(SRC_LAST_ROWS).Offset(.Rows.Count - SRC_LAST_ROWS)
    End With
    
    Dim dws As Worksheet: Set dws = wb.Sheets(DST_NAME)
    Dim dfCell As Range: Set dfCell = dws.Range(DST_FIRST_CELL)
    Dim drg As Range: Set drg = dfCell.Resize(srg.Columns.Count, SRC_LAST_ROWS)
    
    drg.Value = Application.Transpose(srg.Value)
    
    MsgBox "Last " & SRC_LAST_ROWS & " rows transposed.", vbInformation
    
End Sub