How to draw wedge shape with outline in Excel VBA

Question

Using VBA in Excel, I want to create a wedge-shaped section of a circle (the desktop version from Office 365 ProPlus). The code below gives me the correct shape, but the curved section is merely an outline:

Dim myArc as Shape
Set myArc = ActiveSheet.Shapes.AddShape(msoShapeArc, 200, 100, 100, 100)
With myArc
.Adjustments(1) = 0
.Adjustments(2) = 45
.Fill.Visible = msoTrue
End With

Only the curve has an outline; the straight edges are undecorated. How can I completely encircle the shape using an outline? Should I substitute msoShapeArc with another shape? I've tried using the code below to change the line's colour, weight, and visibility, but it only modifies the curved edge, not the straight edges.

With myArc
.Line.ForeColor.RGB = RGB(0, 0, 0)
.Line.Weight = 1
.Line.Visible = msoTrue
End With

I've been able to find documentation on general shape properties, but not which properties apply to which type of shape, and how they actually work to control its appearance.

Answer 1

According to https://learn.microsoft.com/en-us/office/vba/api/excel.adjustments:

Because each adjustable shape has a different set of adjustments, the best way to verify the adjustment behavior for a specific shape is to manually create an instance of the shape, make adjustments with the macro recorder turned on, and then examine the recorded code.

This worked for me to create a pie wedge:

Sub WedgeTest()
    Dim ws As Worksheet, shp As Shape
    Set ws = ActiveSheet
    
    Set shp = ws.Shapes.AddShape(msoShapePie, 50, 50, 100, 100)
    With shp
        .Adjustments.Item(1) = -90 'degrees from 3 oclock
        .Adjustments.Item(2) = -45 'degrees from 3 oclock
        .Fill.Visible = msoFalse
        With .Line
            .Visible = msoTrue
            .ForeColor.RGB = RGB(255, 0, 0)
            .Transparency = 0
        End With
    End With
End Sub